Simple Bar Graph ASP Script

Simple Bar Graph

This script shows how to create a simple bar graph based on numbers pulled from a database. In this example, it will calculate which days this web site gets the most page visits. However, you can use it to display just about any kind of data you wish. It will take the highest number or percentage and use that as your base of 100%. This is almost the same script that I have used at Elvis-Is-Alive.com for the poll. This script also generates a random color for each graph.

Here is the ASP code for this script:

Function RndBGColor()

Randomize Timer

TheRed = Hex(Int(Rnd * 8) * 16)

If Len(TheRed) = 1 Then

TheRed = CStr("0" & TheRed)

End If

TheGreen = Hex(Int(Rnd * 8) * 16)

If Len(TheGreen) = 1 Then

TheGreen = CStr("0" & TheGreen)

End If

TheBlue = Hex(Int(Rnd * 8) * 16)

If Len(TheBlue) = 1 Then

TheBlue = CStr("0" & TheBlue)

End If

RndBGColor = TheRed & TheGreen & TheBlue

End Function

Function BdrColor(BGColor)

TheRed = Left(BGColor,2)

TheGreen = Mid(BGColor,3,2)

TheBlue = Right(BGColor,2)

TheRed = CInt("&H" & TheRed)

TheGreen = CInt("&H" & TheGreen)

TheBlue = CInt("&H" & TheBlue)

TheRed = Hex(TheRed + 127)

TheGreen = Hex(TheGreen + 127)

TheBlue = Hex(TheBlue + 127)

BdrColor = TheRed & TheGreen & TheBlue

End Function

BaseNum = 0

TotalNum = 0

x = 0

TheColor = "000000"

Response.Write "<table style=" & chr(34) & "width:100%;border-style:none;" & chr(34) & ">" & chr(10)

Set objRS = Server.CreateObject ("ADODB.RecordSet")

SqlStr = "SELECT Weekday(WhenVisit) AS WkDayNum, " & _

"Count(Weekday(WhenVisit)) AS NumVisits " & _

"FROM PageVisits " & _

"GROUP BY Weekday(WhenVisit) " & _

"ORDER BY Weekday(WhenVisit)"

objrs.Open SqlStr, PageConStr, adOpenStatic, adLockOptimistic,adCmdText

While Not Objrs.EOF

TotalNum = TotalNum + objrs("NumVisits")

If objrs("NumVisits") > BaseNum Then

BaseNum = objrs("NumVisits")

End If

Objrs.MoveNext

Wend

objrs.Close

objrs.Open SqlStr, PageConStr, adOpenStatic, adLockOptimistic,adCmdText

While Not Objrs.EOF

BGColor = RndBGColor()

ThePerc = FormatNumber((objrs("NumVisits")/TotalNum)*100,2)

TheWidth = FormatNumber((objrs("NumVisits")/BaseNum)*100,0)

Response.Write "<tr>" & chr(10) & _

"<td style=" & chr(34) & "text-align:left;font-size:10pt;padding:3px;" & chr(34) & ">" & chr(10) & _

"<div style=" & chr(34) & "width:" & TheWidth & "%;background-color:#" & BGColor & ";color:#ffffff;font-size:10pt;font-weight:bold;border-style:outset;border-width:2px;border-color:#" & BdrColor(BGColor) & ";padding:3px;" & chr(34) & ">" & chr(10) & _

WeekDayName(objrs("WkDayNum")) & "<br>" & ThePerc & "%" & chr(10) & _

"</div>" & chr(10) & _

"</td>" & _

"</tr>"

x = x + 1

objrs.MoveNext

Wend

objrs.Close

Set objRS = Nothing

Response.Write "</table>"